Adjusted or Unadjusted ODDs Ratio

[waqas imran]

What are the adjusted and unadjusted odds ratio in Bivariate analysis. Are these relevent to Chisquare values or are these another things? Will any body help me calculate it in SPSS. If adjusted arer Chi-Square value then how to calculate  unadjusted Odds in Bivariate analysis through SPSS.

Thankyou mr Bruse for your guidence.

[Ryan]

I'll try to answer your question by borrowing from the post to which I
linked previously. At the end of this post I will simulate data and
run LOGISTIC regression on the simulated data to provide a concrete
example of how to obtain unadjusted and adjusted odds ratios via the
LOGISTIC REGRESSION procedure.

For any generalized linear model [such as logistic regression], there
is a link function that specifies how the the expected value of "Y"
(a.k.a. "E(Y)") and the linear combination of predictors, "eta" are
related. Note that:

eta = b0 + b1*X1 + b2*X2 + ... + bkXk

For the binomial response, the expected value of "Y" can be defined as:

E(Y) = P(Y=1) = exp(eta) / (1 + exp(eta))

The typical link for a binomial response is:

log(p/(1-p)) = eta

which is known as the logit link, where

p = P(Y=1)

*Note: P(Y=0) could also be modeled.

In logistic regression with only one continous predictor, "X1", the
logistic regression equation can be written as:

logit(p) = b0 + b1*X1

The unadjusted odds ratio (OR) associated with "X1" is:

unadjusted OR = exp(b1)

If one were to add the continuous predictor, "X2", (exluding the
interaction between "X1" and "X2"), the equation could be expanded as
follows:

logit(p) = a0 + a1*X1 + a2*X2

The adjusted OR for "X1" is:

adjusted OR = exp(a1)

--------------------------------------

As promised, below I generate data for a logistic regression and fit
the model with only the predictor, "X1", and then another model with
both predictors, "X1" and "X2". All operations are performed using
SPSS syntax (File-->New-->Syntax).

*---------------------------------------------------------------------------------------.
*Generate Data.

set seed 98765432.
new file.

inp pro.

loop ID= 1 to 10000.

    comp X1 = rv.normal(0,1).
    comp X2 = rv.normal(1,2).
    comp b0 = -1.5.
    comp b1 = 0.9.
    comp b2 = 0.5.
    comp eta  = b0 + b1*X1 + b2*X2.
    comp prob = exp(eta) / (1+ exp(eta)).

    comp y = rv.bernoulli(prob).

    end case.
  end loop.
end file.
end inp pro.
exe.

Delete variables b0 b1 b2 eta prob.

*Fit both models.
LOGISTIC REGRESSION VARIABLES y
  /METHOD=ENTER X1
  /METHOD=ENTER X1 X2
  /PRINT=CI(95)
  /CRITERIA=PIN(0.05) POUT(0.10) ITERATE(20) CUT(0.5).
*---------------------------------------------------------------------------------------.

Search for the "Variables in the Equation" Table in the first block.
Note that the unadjusted OR for X1 is 2.194. Next, search for the
Table with the same title in the second block. The adjusted OR for X1
is 2.501.

Ryan

On Wed, Dec 22, 2010 at 2:33 AM, waqas imran <[hidden email]> wrote:

> What are the adjusted and unadjusted odds ratio in Bivariate analysis. Are
> these relevent to Chisquare values or are these another things? Will any
> body help me calculate it in SPSS. If adjusted arer Chi-Square value then
> how to calculate  unadjusted Odds in Bivariate analysis through SPSS.
>
> Thankyou mr Bruse for your guidence.
>
> --
> View this message in context: http://spssx-discussion.1045642.n5.nabble.com/Adjusted-or-Unadjusted-ODDs-Ratio-tp3314671p3314671.html
> Sent from the SPSSX Discussion mailing list archive at Nabble.com.
>
> =====================
> To manage your subscription to SPSSX-L, send a message to
> [hidden email] (not to SPSSX-L), with no body text except the
> command. To leave the list, send the command
> SIGNOFF SPSSX-L
> For a list of commands to manage subscriptions, send the command
> INFO REFCARD
>

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD