SPSSX Discussion

Effect size in ANOVA

Classic

List

Threaded

5 messages Options

E. Bernardo

Effect size in ANOVA

I am using one way ANOVA to test if the means differ across independent groups. I was asked by my critic to report the effect size. What is effect size in ANOVA? Is it the F-value? Please comment.

Eins

Try the latest Yahoo! Search Pad!
Now you can share your online searches with your friends!

Poling, Taylor Leigh

Re: Effect size in ANOVA

Under the analyses drop down menu, test your model using the univariate general linear model analysis, in the options menu you can check 'estimate effect size' in the display options. This will give you partial eta squared values, which is an effect size estimate. You can find a plethora of information on what an effect size estimate is, and the various indicators simply by googling the term. Cohen's standards of small, medium, large are the benchmarks most commonly referred to when reporting effect sizes.

From: SPSSX(r) Discussion on behalf of Eins Bernardo
Sent: Wed 8/5/2009 8:28 PM
To: [hidden email]
Subject: Effect size in ANOVA

I am using one way ANOVA to test if the means differ across independent groups. I was asked by my critic to report the effect size. What is effect size in ANOVA? Is it the F-value? Please comment.

Eins

Try the latest Yahoo! Search Pad!
Now you can share your online searches with your friends!

Marta Garcia-Granero

Re: Effect size in ANOVA

Hi Eins:

There are several measures of effect size in one way ANOVA: eta square
(it will give the same value as partial eta-square in a one way
design), omega square, and f ("f" different from "F",the F value in the
ANOVA table, BTW). You can take a look at them at:
http://web.uccs.edu/lbecker/SPSS/glm_effectsize.htm *.

This syntax computes all of them.

* Example dataset , replace by your own data *.
DATA LIST FREE/iv(F8.0) dv(F8.1).
BEGIN DATA
1 7.5 1 6.2 1 6.9 1 7.4 1 9.2 1 8.3 1 7.6
2 5.8 2 7.3 2 8.2 2 7.1 2 7.8 2 7.2 2 7.3
3 5.9 3 6.2 3 5.8 3 4.7 3 7.3 3 7.2 3 6.2
4 6.2 4 6.8 4 5.7 4 4.9 4 6.2 4 5.8 4 5.4
END DATA.
VALUE LABEL iv 1'NonSmoker' 2'ExSmoker' 3'Smoke<1' 4'Smoke>1'.
VAR LABEL iv 'Smoking status during pregnancy' dv'Baby weight (pounds)'.

MATRIX.
PRINT /TITLE='Omega-square, f & Eta-square'.
GET data /VAR = iv dv /MISSING = OMIT.
COMPUTE n = CSUM(DESIGN(data(:,1))).
COMPUTE k = NCOL(n).
COMPUTE kn=NROW(data).
COMPUTE gsum = T(data(:,2))*DESIGN(data(:,1)).
COMPUTE gsum2= T(data(:,2)&**2)*DESIGN(data(:,1)).
COMPUTE mean = gsum/n.
COMPUTE variance = (gsum2-(gsum&**2)/n)/(n-1).
COMPUTE Iroof = RSUM(gsum2).
COMPUTE Aroof = RSUM((gsum&**2)/n).
COMPUTE Troof = (RSUM(gsum))&**2/kn.
COMPUTE SSE = Aroof - Troof.
COMPUTE MSE = SSE/(k-1).
COMPUTE SSw = Iroof - Aroof.
COMPUTE MSw = SSw/(kn-k).
COMPUTE SST = Iroof - Troof.
COMPUTE Ftest = MSE/MSw.
COMPUTE Fsig = (1-FCDF(Ftest,k-1,kn-k)).
COMPUTE omega2 = (SSE - (k-1)*MSw)/(SST+MSw).
COMPUTE eta2 = SSE/SST.
COMPUTE meann = k/MSUM(1/n).
COMPUTE fvalue=SQRT(Ftest/meann).
PRINT {T(mean),T(SQRT(variance)),T(n)}
/FORMAT='F8.2'
/CLABEL='Mean','SD','N'
/RLABEL='Grp1','Grp2','Grp3','Grp4','Grp5','Grp6','Grp7','Grp8','Grp9','Grp10'
/TITLE='Descriptive statistics'.
PRINT {Ftest,Fsig}
/FORMAT='F8.4'
/CLABEL='F','Sig.'
/TITLE='ANOVA test'.
PRINT {eta2;omega2;fvalue}
/FORMAT='F8.3'
/RLABEL='Eta²','Omega²','f'
/TITLE='Measures of effect size for ONEWAY ANOVA'.
END MATRIX.

* Using UNIANOVA *.
UNIANOVA
dv BY iv
/PRINT = DESCRIPTIVE ETASQ
/DESIGN = iv .

HTH,
Marta GG

Poling, Taylor L wrote:

> Under the analyses drop down menu, test your model using the
> univariate general linear model analysis, in the options menu you can
> check 'estimate effect size' in the display options. This will give
> you partial eta squared values, which is an effect size estimate. You
> can find a plethora of information on what an effect size estimate is,
> and the various indicators simply by googling the term. Cohen's
> standards of small, medium, large are the benchmarks most commonly
> referred to when reporting effect sizes.
>
> ------------------------------------------------------------------------
> *From:* SPSSX(r) Discussion on behalf of Eins Bernardo
> *Sent:* Wed 8/5/2009 8:28 PM
> *To:* [hidden email]
> *Subject:* Effect size in ANOVA
>
> I am using one way ANOVA to test if the means differ across
> independent groups. I was asked by my critic to report the effect
> size. What is effect size in ANOVA? Is it the F-value? Please comment.
>
> Eins
>
>
>
> <http://ph.docs.yahoo.com/searchpad/new7_wonders_of_nature.html>

Evan Harrington, Ph.D.

Re: Effect size in ANOVA

Also be aware, however, that the effect size obtained for the one-way ANOVA reflects an omnibus test. That is, the effect size does not tell you which cells of the design account for the difference between cell means. Although reporting eta square is often what is required in publications, it still does not answer which part of the design is accounting for the change in scores.

Recommended for a discussion of this issue is Rosenthal & Rosnow's Essentials text.

Evan R. Harrington, Ph.D.
Associate Professor
Forensic Thesis Track Director
The Chicago School of Professional Psychology
Department of Forensic Psychology
325 North Wells Street
Chicago, IL 60654

Phone: 312 329-6693
Fax: 312 661-1272
-----Original Message-----
From: SPSSX(r) Discussion [mailto:[hidden email]] On Behalf Of Marta García-Granero
Sent: Thursday, August 06, 2009 1:56 AM
To: [hidden email]
Subject: Re: Effect size in ANOVA

Hi Eins:

There are several measures of effect size in one way ANOVA: eta square
(it will give the same value as partial eta-square in a one way
design), omega square, and f ("f" different from "F",the F value in the
ANOVA table, BTW). You can take a look at them at:
http://web.uccs.edu/lbecker/SPSS/glm_effectsize.htm *.

This syntax computes all of them.

* Example dataset , replace by your own data *.
DATA LIST FREE/iv(F8.0) dv(F8.1).
BEGIN DATA
1 7.5 1 6.2 1 6.9 1 7.4 1 9.2 1 8.3 1 7.6
2 5.8 2 7.3 2 8.2 2 7.1 2 7.8 2 7.2 2 7.3
3 5.9 3 6.2 3 5.8 3 4.7 3 7.3 3 7.2 3 6.2
4 6.2 4 6.8 4 5.7 4 4.9 4 6.2 4 5.8 4 5.4
END DATA.
VALUE LABEL iv 1'NonSmoker' 2'ExSmoker' 3'Smoke<1' 4'Smoke>1'.
VAR LABEL iv 'Smoking status during pregnancy' dv'Baby weight (pounds)'.

MATRIX.
PRINT /TITLE='Omega-square, f & Eta-square'.
GET data /VAR = iv dv /MISSING = OMIT.
COMPUTE n = CSUM(DESIGN(data(:,1))).
COMPUTE k = NCOL(n).
COMPUTE kn=NROW(data).
COMPUTE gsum = T(data(:,2))*DESIGN(data(:,1)).
COMPUTE gsum2= T(data(:,2)&**2)*DESIGN(data(:,1)).
COMPUTE mean = gsum/n.
COMPUTE variance = (gsum2-(gsum&**2)/n)/(n-1).
COMPUTE Iroof = RSUM(gsum2).
COMPUTE Aroof = RSUM((gsum&**2)/n).
COMPUTE Troof = (RSUM(gsum))&**2/kn.
COMPUTE SSE = Aroof - Troof.
COMPUTE MSE = SSE/(k-1).
COMPUTE SSw = Iroof - Aroof.
COMPUTE MSw = SSw/(kn-k).
COMPUTE SST = Iroof - Troof.
COMPUTE Ftest = MSE/MSw.
COMPUTE Fsig = (1-FCDF(Ftest,k-1,kn-k)).
COMPUTE omega2 = (SSE - (k-1)*MSw)/(SST+MSw).
COMPUTE eta2 = SSE/SST.
COMPUTE meann = k/MSUM(1/n).
COMPUTE fvalue=SQRT(Ftest/meann).
PRINT {T(mean),T(SQRT(variance)),T(n)}
/FORMAT='F8.2'
/CLABEL='Mean','SD','N'
/RLABEL='Grp1','Grp2','Grp3','Grp4','Grp5','Grp6','Grp7','Grp8','Grp9','Grp10'
/TITLE='Descriptive statistics'.
PRINT {Ftest,Fsig}
/FORMAT='F8.4'
/CLABEL='F','Sig.'
/TITLE='ANOVA test'.
PRINT {eta2;omega2;fvalue}
/FORMAT='F8.3'
/RLABEL='Eta²','Omega²','f'
/TITLE='Measures of effect size for ONEWAY ANOVA'.
END MATRIX.

* Using UNIANOVA *.
UNIANOVA
dv BY iv
/PRINT = DESCRIPTIVE ETASQ
/DESIGN = iv .

HTH,
Marta GG

Poling, Taylor L wrote:

--
For miscellaneous SPSS related statistical stuff, visit:
http://gjyp.nl/marta/

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD

E. Bernardo

Re: Effect size in ANOVA

I would express my thanks and gratitude to all those who commented this post. Problem already solved.

Best,

Eins

Feel safer online. Upgrade to the new, safer Internet Explorer 8 optimized for Yahoo! to put your mind at peace. It's free.
Get IE8 here!