I can't say I really understand your study, but the general question as to whether the estimated means from the EMMEANS sub-command of the GENLIN procedure take into account an offset is worth exploring. Consequently, I decided to generate data from a negative binomial regression with a single categorical (dichotomous) predictor and an offset, along with a random intercept to incorporate within-subject correlation. I then fit a GEE negative binomial model using the GENLIN procedure on the simulated data. What did I find? The EMMEANS sub-command does in fact take into account the offset.
For those interested, the SPSS syntax used to perform this simulation experiment is provided below.
Ryan
--
*Generate Data.
set seed 895795432.
new file.
inp pro.
comp ID=-99.
comp mean_habitat1 = -99.
comp mean_habitat2 = -99.
comp habitat = -99.
comp offset_1=-99.
comp rand_eff = -99.
leave ID to rand_eff.
loop ID= 1 to 100000.
comp rand_eff = sqrt(0.025)*rv.normal(0,1).
loop time = 1 to 2.
comp mean_habitat1 = 10.0.
comp mean_habitat2 = 20.0.
comp b0 = ln(mean_habitat2).
comp b1 = ln(mean_habitat1) - ln(mean_habitat2).
comp habitat = rv.bernoulli(0.50).
comp offset_1=rnd(rv.uniform(10,100)).
comp ln_offset_1 = ln(offset_1).
comp lambda = exp(b0 + b1*(habitat=0) + ln_offset_1 + rand_eff).
comp shape = 0.8.
comp dispersion = 1 / shape.
comp scale = lambda / shape.
comp mean = rv.gamma(shape, 1/scale).
comp y = rv.poisson(mean).
end case.
end loop.
end loop.
end file.
end inp pro.
exe.
delete variables mean_habitat1 mean_habitat2 b0 b1 lambda shape scale dispersion mean b0 b1 rand_eff.
* Generalized Estimating Equations.
GENLIN y BY habitat (ORDER=ASCENDING)
/MODEL habitat INTERCEPT=YES OFFSET=ln_offset_1
DISTRIBUTION=NEGBIN(MLE) LINK=LOG
/EMMEANS TABLES=habitat SCALE=ORIGINAL COMPARE=habitat CONTRAST=PAIRWISE PADJUST=LSD
/REPEATED SUBJECT=ID WITHINSUBJECT=time SORT=YES CORRTYPE=EXCHANGEABLE ADJUSTCORR=YES COVB=ROBUST
/PRINT CPS DESCRIPTIVES MODELINFO FIT SUMMARY SOLUTION (EXPONENTIATED).
COMPUTE y_offset=y/offset_1.
EXECUTE.
EXAMINE VARIABLES=y_offset BY habitat
/PLOT NONE
/STATISTICS DESCRIPTIVES
/CINTERVAL 95
/MISSING LISTWISE
/NOTOTAL.
>
> I am using a repeated measures, negative binomial generalized estimating
> equation (GEE) to analyze my study where I counted animals on forest
> transects that sample 2 habitats. The habitats were not evenly sampled (it
> wasn't possible) so I have an offset variable of area sampled.
>
> This works fine for the GEE, but the estimated marginal mean contrast seems
> not to incorporate the offset (area sampled) because it appears to test for
> differences in the average number of individuals sighted per transect with
> no consideration of area sampled. When I convert the average number of
> individuals to a density (EMM of average number of individuals/average area
> sampled) the relationship between the two variables often reverses (the
> smaller EMM becomes larger when expressed in terms of individuals/area).
>
> Is there a way to incorporate an offset variable into the SPSS GEE EMM
> statement? Or am I restricted to reporting the GEE results and the simple
> (EMMs/area) without doing a pairwise contrasts between them?
> Thanks.
>
>
> --
> Sent from the SPSSX Discussion mailing list archive at Nabble.com.
>
> =====================
> To manage your subscription to SPSSX-L, send a message to
> command. To leave the list, send the command
> SIGNOFF SPSSX-L
> For a list of commands to manage subscriptions, send the command
> INFO REFCARD
Locked
