SPSSX Discussion

Poisson regression - New cases of cancer

Classic

List

Threaded

2 messages Options

Yves_Therriault

Poisson regression - New cases of cancer

Hello to all SPSSers,

I'm a research analyst in public health. I'm collaborating on a paper
regarding cancer in our region (North Shore of St.Lawrence River - Québec,
Canada). This paper will be published next fall. I'd like to use Poisson
regression in order to "predict" the incidence of cancer for the next few
years (2003 to 2011). I'm using SPSS 12.0.1. I would appreciate very much
if I could get a example of code to do Poisson regression with my data. I
know there is no procedure available in SPSS for Poisson Regression.
However, I've heard that it's possible to "trick" SPSS to do Poisson
regression.

In fact, what I'm looking for is 2 syntax programmes : the first one for
"predicting" the number of cases and the second one for "predicting" the
cancer incidence rate (per 100 000 people).

Of course, it would be more appropriate to make "predictions" for each
siege, but the total number of cancer cases in the North Shore region is
relatively too small (on my humble opinion) to allow that.

My SPSS file contains 4 variables. Year, total population of the North
Shore, total number of people who is at least 60 years old, the number of
new cases of cancer. The year 2002 is the last one for which database about
cancer is available at the provincial level (Québec).

Année Population Pop60et+ Nouveaux_cas_cancer
1992 105892 10165 405
1993 105443 10587 405
1994 104556 10974 442
1995 104583 11340 449
1996 104723 11581 445
1997 104445 12206 425
1998 103489 12631 479
1999 102430 13073 486
2000 101087 13557 470
2001 99761 13699 478
2002 98583 14399 495

Thanks in advance !

Best regards,

Yves Therriault, Ph. D.
Agent de recherche
Direction de la santé publique
Agence de la santé et des services sociaux de la Côte-Nord
Baie-Comeau (Qc)

P.S. Sincere apologies for the very bad English.

Marta García-Granero

Re: Poisson regression - New cases of cancer

Bon soir Yves,

(mon français est mauvais aussi)

I'll send you directly a PDF document with 2 pages of "Statistics at
Square Two" book dedicated to Poisson regression models.

* Sample dataset for Poisson regression using Gen Log *.
DATA LIST list / id(f2.0) agegroup(f8.0) smoker(f1.0) pyears(f8.0) deaths(f4.0).
BEGIN DATA
1 0 0 18790 2
2 1 0 10673 12
3 2 0 5712 28
4 3 0 2585 28
5 4 0 1462 31
6 0 1 52407 32
7 1 1 43248 104
8 2 1 28612 206
9 3 1 12663 186
10 4 1 5317 102
END DATA.
DOCUMENT 'Coronary deaths from British male doctors. Doll & Hill
(Nat Cancer Inst Monog 1996; 19:205-68)'.
VARIABLE LABELS agegroup "Age group".
VALUE LABELS agegroup
0 "35-44 years"
1 "45-54 years"
2 "55-64 years"
3 "65-74 years"
4 "75-84 years".
VARIABLE LABELS smoker "Smoking status".
VALUE LABELS smoker
0 "No"
1 "Yes".
WEIGHT BY deaths .

DISPLAY DICTIONARY.

COMPUTE age=40 + agegroup*5.
FORMATS age(F8.0).
EXECUTE.

* GENLOG needs that the reference cathegory is last *

RECODE agegroup (0=5) .
ADD VALUE LABELS agegroup 0 "" 5 "35-44 years".
RECODE smoker (0=2) .
ADD VALUE LABELS smoker 0 "" 2 "No".
EXECUTE.

FREQUENCIES
VARIABLES=agegroup smoker
/ORDER VARIABLES .

* Univariate analysis *.
GENLOG
agegroup smoker /CSTRUCTURE=pyears
/MODEL=POISSON
/PRINT FREQ RESID ESTIM
/PLOT NONE
/CRITERIA =DELTA(0)
/DESIGN agegroup .
GENLOG
agegroup smoker /CSTRUCTURE=pyears
/MODEL=POISSON
/PRINT FREQ RESID ESTIM
/PLOT NONE
/CRITERIA =DELTA(0)
/DESIGN smoker .

* Main effects model *.
GENLOG
agegroup smoker /CSTRUCTURE=pyears
/MODEL=POISSON
/PRINT FREQ RESID ESTIM
/PLOT NONE
/CRITERIA =DELTA(0)
/DESIGN agegroup smoker .

* Interaction term *.
GENLOG
agegroup smoker /CSTRUCTURE=pyears
/MODEL=POISSON
/PRINT ESTIM
/PLOT NONE
/DESIGN agegroup smoker agegroup*smoker .

* Using age (quantitative) insted of agegroup *.
* Yo need an ID variable (it exists in the dataset, if not, create it
this way: COMPUTE id=$casenum.

* Full model with age instead of agegroup *.
GENLOG
id smoker WITH age /CSTRUCTURE=pyears
/MODEL=POISSON
/PRINT ESTIM
/PLOT NONE
/DESIGN age smoker age*smoker .

HTH,

Marta

YT> I'm a research analyst in public health. I'm collaborating on a paper
YT> regarding cancer in our region (North Shore of St.Lawrence River - Québec,
YT> Canada). This paper will be published next fall. I'd like to use Poisson
YT> regression in order to "predict" the incidence of cancer for the next few
YT> years (2003 to 2011). I'm using SPSS 12.0.1. I would appreciate very much
YT> if I could get a example of code to do Poisson regression with my data. I
YT> know there is no procedure available in SPSS for Poisson Regression.
YT> However, I've heard that it's possible to "trick" SPSS to do Poisson
YT> regression.

YT> In fact, what I'm looking for is 2 syntax programmes : the first one for
YT> "predicting" the number of cases and the second one for "predicting" the
YT> cancer incidence rate (per 100 000 people).

YT> Of course, it would be more appropriate to make "predictions" for each
YT> siege, but the total number of cancer cases in the North Shore region is
YT> relatively too small (on my humble opinion) to allow that.

YT> My SPSS file contains 4 variables. Year, total population of the North
YT> Shore, total number of people who is at least 60 years old, the number of
YT> new cases of cancer. The year 2002 is the last one for which database about
YT> cancer is available at the provincial level (Québec).

YT> Année Population Pop60et+ Nouveaux_cas_cancer
YT> 1992 105892 10165 405
YT> 1993 105443 10587 405
YT> 1994 104556 10974 442
YT> 1995 104583 11340 449
YT> 1996 104723 11581 445
YT> 1997 104445 12206 425
YT> 1998 103489 12631 479
YT> 1999 102430 13073 486
YT> 2000 101087 13557 470
YT> 2001 99761 13699 478
YT> 2002 98583 14399 495