SPSS/PASW 18 bootstrapping module - does anyone have this (in Melbourne, Vic, Australia)

[Heather Gibbs]

Hi,

 

I'm new to the list and get SPSS through uni (am doing a PhD) but unfortunately they can't supply me with the bootstrapping module (and I can't really afford a load of time, or money, just to get some "souped up" standard errors when I should be finishing up)

 

I did try doing bootstrapping via the "non-linear" regression in SPSS

(see e.g. http://www.atlas.illinois.edu/support/stats/resources/spss/bootstrapping--simple-linear-regression.pdf)

 

But a) its pretty slow having to specify the equation in full including the estimated parameter values and b) I'm not convinced the results always make sense (but that could be just me!)

 

Basically I would love to be able to try out the bootstrapping module for comparison if someone in Melbourne, Vic, Australia has a copy and I could bring my data and run it through (should only take a few minutes, ok, maybe an hour!)

 

Or - have any opinions on whether it is worth forking out $600+ US for it - which seems to be the going rate (despite the CD I have from SPSS claiming on the front that it CONTAINS the module, it doesn't - very frustrating!)

 

Thanks

Heather Gibbs

Deakin University, Melbourne, Vic, Australia

[Michael Kruger]

Heather,


See the below link from Raynauls's SPSS help site:

http://pages.infinit.net/rlevesqu/SampleSyntax.htm#Bootstrap


Search for 'bootstrap' when you get to the above URL...


I have used it successfully with a little tweaking to do a variety of
bootstrapping analyss.

i have also attached a text file which provides the syntax from the
above link


MK

***oms_bootstrapping.sps***.
***if c:\temp is not a valid drive\path, replace all instances of c:\temp
   with a valid drive\path.

PRESERVE.
SET TVARS NAMES.

*first OMS command just suppresses Viewer output.
OMS /DESTINATION VIEWER=NO /TAG='suppressall'.

*select regression coefficients tables and write to data file.
OMS /SELECT TABLES
    /IF COMMANDS=['Regression'] SUBTYPES=['Coefficients']
    /DESTINATION FORMAT=SAV OUTFILE='c:\temp\temp.sav'
   /COLUMNS DIMNAMES=[ 'Variables'  'Statistics']
   /TAG='reg_coeff'.

*define a macro to draw samples with replacement and
 run Regression commands.
DEFINE regression_bootstrap (samples=!TOKENS(1)
                                           /depvar=!TOKENS(1)
                                           /indvars=!CMDEND)

COMPUTE dummyvar=1.
AGGREGATE
  /OUTFILE='c:\temp\aggrtemp.sav'
  /BREAK=dummyvar
  /filesize=N.
MATCH FILES FILE=* /TABLE='c:\temp\aggrtemp.sav'
  /BY dummyvar.
!DO !other=1 !TO !samples
SET SEED RANDOM.
WEIGHT OFF.
FILTER OFF.
DO IF $casenum=1.
- COMPUTE #samplesize=filesize.
- COMPUTE #filesize=filesize.
END IF.
DO IF (#samplesize>0 and #filesize>0).
- COMPUTE sampleWeight=rv.binom(#samplesize, 1/#filesize).
- COMPUTE #samplesize=#samplesize-sampleWeight.
- COMPUTE #filesize=#filesize-1.
ELSE.
- COMPUTE sampleWeight=0.
END IF.
WEIGHT BY sampleWeight.
FILTER BY sampleWeight.
REGRESSION
  /STATISTICS COEFF
  /DEPENDENT !depvar
  /METHOD=ENTER !indvars.
!DOEND
!ENDDEFINE.

***insert any valid path\data file name***.
GET FILE='c:\Program Files\SPSS\Employee data.sav'.

***Call the macro, and specify number of samples,
   dependent variable, and independent variables.
regression_bootstrap
   samples=100
   depvar=salary
   indvars=salbegin  jobtime .

OMSEND.

GET FILE 'c:\temp\temp.sav'.

FREQUENCIES
  VARIABLES=salbegin_B salbegin_Beta jobtime_B jobtime_Beta
  /FORMAT NOTABLE
  /PERCENTILES= 2.5 97.5
  /HISTOGRAM NORMAL.

RESTORE.

[Waleed Massoud]

I am using SPSS to make ANCOVA, I want to know how to compute df for the correct model, intercept, and the covariate variable.
Can anybody help me ?
Thanks in advance

[Marta Garcia-Granero]

Waleed Massoud wrote:
> I am using SPSS to make ANCOVA, I want to know how to compute df for
> the correct model, intercept, and the covariate variable.

SPSS should give those values, no need to compute them by hand...

--
For miscellaneous SPSS related statistical stuff, visit:
http://gjyp.nl/marta/

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD