"Now let's wait for David to show us a neat MATRIX method for doing the same thing. ;-)".
You scoundrel [FILTERED] !! You knew I would bite! ;-))).
Actually needed a short break from my nervous breakdown .
*---Simulate some data ---*.
INPUT PROGRAM.
NUMERIC VAR01 TO VAR35 (F8.3).
VECTOR VAR=VAR01 TO VAR35 .
LOOP CASE=1 TO 300.
+ COMPUTE VAR(1)= NORMAL(1).
+ LOOP #=2 TO 35.
+ COMPUTE VAR(#)=VAR(#-1)*.80+ NORMAL(1).
+ END LOOP.
+ END CASE.
END LOOP.
END FILE.
END INPUT PROGRAM.
EXECUTE .
DATASET NAME RAW.
**-----Uses first variable in file as dependent. The rest are entered as independent individually**.
DATASET DECLARE REG.
MATRIX.
GET DATA /FILE * / VAR ALL.
COMPUTE Y=DATA(:,1).
COMPUTE ONE=MAKE(NROW(DATA),1,1).
LOOP #=2 TO NCOL(DATA).
COMPUTE X={ONE,DATA(:,#)}.
SAVE (T(GINV(T(X)*X )*T(X)*Y)) / OUTFILE reg /VARIABLES Const B1.
END LOOP.
END MATRIX.
**--There may be a cleaner way to merge in the variable names --*.
DATASET ACTIVATE RAW.
DATASET COPY Rawcopy.
SELECT IF $CASENUM=1.
FLIP.
SELECT IF CASE_LBL NE "VAR01".
MATCH FILES FILE * / FILE REG.
EXECUTE.
DELETE VARIABLES Var001.
FORMATS ALL (F10.8).
Bruce Weaver wrote
I would suggest using something other than !var as your macro name. How about !MyReg instead?
* Example using 1991 GSS data file.
new file.
dataset close all.
get file = "C:\SPSSdata\1991 U.S. General Social Survey.sav".
dataset name raw.
DEFINE !MyReg (items = !CMDEND)
!DO !vara !IN (!items)
REGRESSION
/MISSING LISTWISE
/STATISTICS COEFF
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT prestg80
/METHOD=ENTER !vara.
!DOEND
!ENDDEFINE.
* OMS.
DATASET DECLARE Coeff.
OMS
/SELECT TABLES
/IF COMMANDS=['Regression'] SUBTYPES=['Coefficients']
/DESTINATION FORMAT=SAV NUMBERED=TableNumber_
OUTFILE='Coeff'.
!MyReg items = age educ paeduc maeduc speduc.
OMSEND.
dataset activate Coeff.
select if Var2 NE "(Constant)".
list Var2 B.
* Use DELETE VARIABLES if you want to delete variables other than Var2 and B.
* Var2 could be AUTORECODEd to numeric too.
Now let's wait for David to show us a neat MATRIX method for doing the same thing. ;-)
Riya wrote
Hey Everyone,
I am running a simple regression analysis including 26 variables. Taking 2 variables at a time , one variable would be dependent and other one would be independent one. For 26 variables , i have to perform this task 25 times. I thought to automate this using SPSS macro. I succeeded it to a some extent. However, my requirement is to save UNSTANDARDIZED BETA ONLY for all the 25 independent variables to a single data file in SPSS or excel .
Following the syntax that i developed :
DEFINE !var (items = !CMDEND)
!DO !vara !IN (!items)
REGRESSION
/MISSING LISTWISE
/STATISTICS COEFF
/CRITERIA=PIN(.05) POUT(.10)
/NOORIGIN
/DEPENDENT var1
/METHOD=ENTER !vara.
!DOEND
!ENDDEFINE.
!var items= var2 var3.
I know how to export the output using OMS and selecting a particular table. But that will create multiple datasets. I wish to collaborate them in a single datafile.
Thanks and Regards
Riya
Please reply to the list and not to my personal email.
Those desiring my consulting or training services please feel free to email me.
---
"Nolite dare sanctum canibus neque mittatis margaritas vestras ante porcos ne forte conculcent eas pedibus suis."
Cum es damnatorum possederunt porcos iens ut salire off sanguinum cliff in abyssum?"
Locked
