Oooops, I hit "Send" by mistake before answering (must be the Friday
spirit)....
Sorry for the useless previous message.
Marta
> I would like to see if the difference between correlations coefficients are
> significant when comparing males and females on the same variable of
> interest. How would i do this in SPSS?
>
Hi
Since both groups are independent, you can use Fisher's transformation
and run a Z test:
Group A: Ra, Na
Group B: Rb, Nb
RZa=0.5*LN((1+Ra)/(1-Ra))
SEa=SQRT(1/(Na-3))
RZb=0.5*LN((1+Rb)/(1-Rb))
SEb=SQRT(1/(Nb-3))
Z=(RZa-RZb)/SQRT(SEa^2+SEb^2)
The result is significant if ABS(Z) > 1.96.
You can use MATRIX:
* Assuming Ra=0.5, Na=30; Rb=0.7, Nb=50 *.
MATRIX.
PRINT /TITLE='COMPARING TWO INDEPENDENT CORRELATION COEFFICIENTS'.
* Input data, replace by your own *.
COMPUTE r1=0.5.
COMPUTE n1=30.
COMPUTE r2=0.7.
COMPUTE n2=50.
PRINT {r1,r2}
/FORMAT='F8.2'
/CLABELS='R1' 'R2'
/TITLE='Correlation values being compared:'.
PRINT {n1,n2}
/FORMAT='F8.0'
/CLABELS='N1','N2'
/TITLE='Sample sizes:'.
COMPUTE zr1=.5*(LN((1+r1)/(1-r1))).
COMPUTE varzr1=1/(n1-3).
COMPUTE zr2=.5*(LN((1+r2)/(1-r2))).
COMPUTE varzr2=1/(n2-3).
COMPUTE z=ABS(zr1-zr2)/SQRT(varzr1+varzr2).
COMPUTE z_sig=2*(1-CDFNORM(z)).
PRINT {z,z_sig,(z_sig/2)}
/FORMAT='F8.3'
/CLABELS='Z' '2-tails' '1-tail'
/TITLE='Z value and significance (2-tailed & 1-tailed)'.
END MATRIX.
HTH,
Marta García-Granero
--
For miscellaneous statistical stuff, visit:
http://gjyp.nl/marta/=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD
Locked
