Re: ANCOVA SPSS Question HELP

Posted by Bruce Weaver on Sep 07, 2016; 10:36pm
URL: http://spssx-discussion.165.s1.nabble.com/ANCOVA-SPSS-Question-HELP-tp5733064p5733073.html

Given what you have said here and in your later post, I agree that ANCOVA (with both PreTestSum and Moderator as covariates) is generally preferred to 3x2 mixed design ANOVA that treats Time as a factor.  E.g., see this BMJ note:

  http://www.ncbi.nlm.nih.gov/pmc/articles/PMC1121605/

In the GUI dialog for GLM > Univariate (UNIANOVA):

PostTest Sum = Dependent variable
Group Assignment = Fixed Factor
PreTest Sum = Covariate
Moderating Variable Y = Covariate

If you exit via PASTE, the key parts of the pasted syntax should look something like this:

UNIANOVA PostTestSum BY Group WITH PreTestSum Moderator
 /DESIGN = Group PreTestSum Moderator Group*Moderator
.

You'll have to fill in your own variable names, obviously.

Here is a fuller example that you may find helpful.  Notice the use of several EMMEANS to get the 3 pair-wise comparisons among groups at various values of the Moderator variable.  I set the value of PreTestSum to 50 for all of them, because the differences among treatment means will not depend on the value of PreTestSum if it does not interact with Group.  

HTH.


* Generate some sample data.
* The following code is a modified version of code Jeff Miller
* posted a couple days ago in another thread.

* Set the RNG seed so that the results are reproduced exactly.
set RNG=MT MTINDEX=121314.15.

new file.
input program.

compute #SampleSize = 50.

loop #i = 1 to #SampleSize.
   compute group = 1.
   compute PostTestSum = rv.normal(50,10).
   compute PreTestSum = rv.normal(50,10).
   compute Moderator = rv.uniform(10,50).
   end case.
end loop.
loop #i = 1 to #SampleSize.
   compute group = 2.
   compute PostTestSum = rv.normal(50,10).
   compute PreTestSum = rv.normal(50,10).
   compute Moderator = rv.uniform(10,50).
   end case.
end loop.
loop #i = 1 to #SampleSize.
   compute group = 3.
   compute PostTestSum = rv.normal(50,10).
   compute PreTestSum = rv.normal(50,10).
   compute Moderator = rv.uniform(10,50).
   end case.
end loop.

end file.
end input program.
execute.
formats group(f1).

UNIANOVA PostTestSum BY group WITH PreTestSum Moderator
  /DESIGN=PreTestSum Moderator group Moderator*group
  /EMMEANS=TABLES(group) WITH(PreTestSum=50 Moderator=10) COMPARE
  /EMMEANS=TABLES(group) WITH(PreTestSum=50 Moderator=20) COMPARE
  /EMMEANS=TABLES(group) WITH(PreTestSum=50 Moderator=30) COMPARE
  /EMMEANS=TABLES(group) WITH(PreTestSum=50 Moderator=40) COMPARE
  /EMMEANS=TABLES(group) WITH(PreTestSum=50 Moderator=50) COMPARE
.

James Ross wrote

Hello,

I am using SPSS 24 and I have an ANCOVA related question.

I have a 3 group (Treatment A, Treatment B, Control) repeated measures design.

I have a pretest and a posttest for each group.

I also measured a trait (Variable Y) that is a continuous (with a sum range between 10-50) variable. My hypothesis is that this variable will moderate effects of treatments.

I thought this was a simple ANCOVA process in SPSS, but I don't know what to put in "Dependent Variable," "Fixed Factor(s)," "Random Factor(s), "Covariate(s)." I am seeing these options under the "General Linear Model" - "Univariate" menu option.

In other words, where do I put these:

PreTest Sum
PostTest Sum
Group Assignment
Moderating Variable Y

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD