Re: ways to describe the MANOVA effect

Posted by Bruce Weaver on Jan 14, 2020; 4:42pm
URL: http://spssx-discussion.165.s1.nabble.com/ways-to-describe-the-MANOVA-effect-tp5738769p5738772.html

Disclaimer:  I'm no expert in multivariate models, but I think the usual
approach would be to look at a plot showing the centroids for the 3 groups.
Here's some SPSS syntax that might be close to what you want (using Jim
Frost's CSV data file from that site).   HTH.


PRESERVE.
SET DECIMAL DOT.

GET DATA  /TYPE=TXT
  /FILE="C:\bw\SPSS\data\MANOVA_example.csv"
  /ENCODING='UTF8'
  /DELIMITERS=","
  /QUALIFIER='"'
  /ARRANGEMENT=DELIMITED
  /FIRSTCASE=2
  /DATATYPEMIN PERCENTAGE=95.0
  /VARIABLES=
  Method AUTO
  Test AUTO
  Satisfaction AUTO
  /MAP.
RESTORE.
CACHE.

GRAPH
  /SCATTERPLOT(BIVAR)=Satisfaction WITH Test BY Method
  /MISSING=LISTWISE
  /TITLE='Scatterplot of Test vs Satisfaction'.

CORRELATIONS Satisfaction with Test.

* The MANOVA model.
GLM Test Satisfaction BY Method
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /PRINT=DESCRIPTIVE
  /CRITERIA=ALPHA(.05)
  /DESIGN= Method.

* Use DISCRIMINANT to plot the centroids.
DISCRIMINANT Groups=Method(1,3)
 /VARIABLES=Satisfaction Test
 /PLOT=COMBINED.

* Alternative approach:  ANCOVA with Y=Test, Covariate = Satisfaction.

UNIANOVA Test BY Method WITH Satisfaction
  /METHOD=SSTYPE(3)
  /INTERCEPT=INCLUDE
  /EMMEANS=TABLES(Method) WITH(Satisfaction=MEAN) COMPARE ADJ(LSD)
  /CRITERIA=ALPHA(0.05)
  /DESIGN=Satisfaction Method.



pji wrote

> Hello,
> I came across this blog post on this website:
> https://statisticsbyjim.com/anova/multivariate-anova-manova-benefits-use/.
> I am curious about the figure with the Scatterplot of Test vs.
> Satisfaction, with satisfaction on the X axis, test on the Y axis, and the
> three Methods as separate plot points on the graph.
>
> My question is, in SPSS, what part of the output do I examine to determine
> the nature of the multi-variate effect? Based on the example and
> explanation on the website, it would seem that to arrive at the conclusion
> that there is a multi-variate effect, you have to plot the effect by using
> a scatterplot. To arrive at the conclusion about the multivariate effect
> of the teaching method on both satisfaction and test score, you have to
> heuristically examine the scatterplot. Is there any section in the SPSS
> MANOVA output that serves as an indicator to support the description about
> the nature of the multi-variate effect? Or do I just obtain the MANOVA
> test (e.g., Wilks' test) that indicates that there is a multivariate
> effect, and then to describe the actual multivariate effect, I would have
> to construct a scatterplot and base my description on a heuristic
> examination of the scatterplot? If so, then it seems archaic to describe
> the multivariate effect simply based on a heuristic examination. It would
> be better if there was a section of the MANOVA output that I could
> reference that would provide the statistical results that I could cite to
> describe the nature of the multivariate effect.
> Thanks in advance.
> Peter Ji
>
>
> =====================
> To manage your subscription to SPSSX-L, send a message to

> LISTSERV@.UGA

>  (not to SPSSX-L), with no body text except the
> command. To leave the list, send the command
> SIGNOFF SPSSX-L
> For a list of commands to manage subscriptions, send the command
> INFO REFCARD





-----
--
Bruce Weaver
[hidden email]
http://sites.google.com/a/lakeheadu.ca/bweaver/

"When all else fails, RTFM."

NOTE: My Hotmail account is not monitored regularly.
To send me an e-mail, please use the address shown above.

--
Sent from: http://spssx-discussion.1045642.n5.nabble.com/

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD