Hi,
I have a daily windows batch job which runs four SPSS production facility scripts. This will run in one cmd promt window, no SPSS windows are opened. One should not work on SPSS while this script is running. Therefore it is started by windows as a planned task every night at 22:00.
The script below should be saved with the lastname cmd. You need to edit lines 12-14, 39, 46, 53 and 60 to adapt it to your own setup and to name the production facility scripts you want to run.
Best,
Eero
:: made for Windows 7 and SPSS 21 by Eero Olli.
:: Edited 15.09.2011 to work on portable computers.
:: upgraded to v20 15.03.2012
:: upgraded to SPSS v21 05.06.2013
@ECHO off
ECHO Running now M:\dokumentasjon\SPSS-produksjon\update all SPSSv21.cmd
:: These variables need to be changed when the setup is changed
set scriptdrive=M:
set scriptfolder=dokumentasjon\SPSS-produksjon\
set SPSSlocation=C:\Programfiler\IBM\SPSS\Statistics\21
set program="%SPSSlocation%\stats.exe"
:: The structure of the script
ECHO ON
call :_timestamp1
ECHO off
call :_KillSPSS
call :_chkspssw
call :_location
ECHO ON
call :_update1
call :_update2
call :_update3
call :_update4
call :_KillSPSS
call :_timestamp2
GOTO :EOF
:: the components which are called above:
:: order of components does not matter below.
:_update1
set skript="oppdater LDOsaker - del 1 SQLwebsak.spj"
CALL :_chkscript
ECHO Grab data from SQL server and other sources
IF exist %skript% (start /wait "SPSS" %program% %skript% -production)
GOTO :EOF
:_update2
set skript="M:\dokumentasjon\SPSS-produksjon\oppdater LDOsaker - del 2 skjemaer.spj"
CALL :_chkscript
ECHO Update data from SelectSurvey forms
IF exist %skript% (start /wait "SPSS" %program% %skript% -production)
GOTO :EOF
:_update3
set skript="M:\dokumentasjon\SPSS-produksjon\oppdater LDOsaker - del 3 koble.spj"
CALL :_chkscript
ECHO Update join all datasources to one big file and copy parts to SQL and ACCESS
IF exist %skript% (start /wait "SPSS" %program% %skript% -production)
GOTO :EOF
:_update4
set skript="M:\dokumentasjon\SPSS-produksjon\oppdater LDOsaker - del 4 - tabeller.spj"
CALL :_chkscript
ECHO Update all lists, tables and figures
IF exist %skript% (start /wait "SPSS" %program% %skript% -production)
GOTO :EOF
:_location
%scriptdrive%
cd \%scriptfolder%
::ECHO script started %date% %time%
ECHO.
GOTO :EOF
:_chkscript
ECHO "**********************"
IF exist %scriptfile% (ECHO productionscript is located ) ELSE GOTO :_problem
GOTO :EOF
:_KillSPSS
ECHO make sure that spss production facility is not in use
setlocal
tasklist|find "stats.com">nul
if %errorlevel% EQU 0 (
ECHO.
ECHO SPSS Production facility is in use.
ECHO it will be forcedly shut down. Sorry!
ECHO.
taskkill /f /im stats.com
) ELSE (
ECHO.
echo SPSS Production facility is available
ECHO.
)
endlocal & GOTO :EOF
:_chkspssw
ECHO make sure that SPSS is not in use
setlocal
tasklist|find "spssengine.exe">nul
if %errorlevel% EQU 0 (
ECHO.
ECHO SPSS is already in use.
ECHO it will be forcedly shut down. Sorry!
ECHO.
taskkill /f /im spssengine.exe
) ELSE (
ECHO.
ECHO SPSS is available
ECHO.
)
endlocal & GOTO :EOF
:_timestamp1
ECHO.
ECHO script started at %date% %time%
ECHO.
C:\Python27\python.exe m:\dokumentasjon\python\beep_ok.py
GOTO :EOF
:_timestamp2
ECHO.
ECHO script finished at %date% %time%
ECHO.
C:\Python27\python.exe m:\dokumentasjon\python\beep_ok.py
GOTO :EOF
:_problem
ECHO something went wrong.
C:\Python27\python.exe m:\dokumentasjon\python\beep_error.py
pause
exit.
endlocal & GOTO :EOF
.
-----Opprinnelig melding-----
Fra: albert_sun [mailto:
[hidden email]]
Sendt: 28. oktober 2013 00:47
Emne: How to let SPSS run at the back
Hi, all:
I am running a SPSS synatx (takes some time), and the data constantly pop up to the front. I am thinking of if there is any way to put SPSS running at the back so that I could do other things while it is running.
--
View this message in context:
http://spssx-discussion.1045642.n5.nabble.com/How-to-let-SPSS-run-at-the-back-tp5722749.htmlSent from the SPSSX Discussion mailing list archive at Nabble.com.
=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD
Locked
it worked like a charm.
