The Marascuillo Procedure or similar

[Samir Omerovic]

Dear all,

I have following problem: I have sample of 500 respondents who answered a questionnaire. One of the question was to associate different statements with different brands and multiple choice was allowed. So statement 1 could be associated with brand 1, brand 2 etc.... In total I have some 15 statements and 16 brands (and all possible associations are possible). As a result of analysis I would need to calculate in percentages how many respondents associates statement 1 with each of brands etc. and at the end I need to say that percentage of those who associate statement 1 with brand 1 is statistically different from percentage of those who associate statement 1 with brand 2 etc... I am just beginner in statistics and know basics very well but I found Marascuillo procedure to be able to simultaneously test differences in all pairs of proportions but I can not do this in SPSS.
Is there something else I can do in SPSS to calculate this kind of statistics?


Thanks in advance

Samir

===================== To manage your subscription to SPSSX-L, send a message to [hidden email] (not to SPSSX-L), with no body text except the command. To leave the list, send the command SIGNOFF SPSSX-L For a list of commands to manage subscriptions, send the command INFO REFCARD

[Marta Garcia-Granero]

Samir Omerovic wrote:

> I have following problem: I have sample of 500 respondents who
> answered a questionnaire. One of the question was to associate
> different statements with different brands and multiple choice was
> allowed. So statement 1 could be associated with brand 1, brand 2
> etc.... In total I have some 15 statements and 16 brands (and all
> possible associations are possible). As a result of analysis I would
> need to calculate in percentages how many respondents associates
> statement 1 with each of brands etc. and at the end I need to say that
> percentage of those who associate statement 1 with brand 1 is
> statistically different from percentage of those who associate
> statement 1 with brand 2 etc... I am just beginner in statistics and
> know basics very well but I found Marascuillo procedure to be able to
> simultaneously test differences in all pairs of proportions but I can
> not do this in SPSS.
> Is there something else I can do in SPSS to calculate this kind of
> statistics?

I have found a good description of the method at
http://www.itl.nist.gov/div898/handbook/prc/section4/prc474.htm

It looks fairly simple.

Anyway, when I looked at the description of the method and a sample
dataset
(http://www.itl.nist.gov/div898/handbook/prc/section4/prc46.htm#Example)
I got the impression that the method was good for INDEPENDENT samples,
while I think, by the description you give of your data, that you have
MATCHED data (same respondents for every statement&question). Is that
true or perhaps I misunderstood you?

Give me a couple of hours, I might be able to write something using
MATRIX. Could you send me (privately if you don't want to send your data
all over the web) a small sample of your data (to see the way they are
coded...)?.

Marta

--
For miscellaneous statistical stuff, visit:
http://gjyp.nl/marta/

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD

[Ergul, Emel A.]

dear all:

 

finally  I am diverted to the mac version of SPSS v.17. However, every time I run syntax I receive "pyhton scripts cannot be executed. Please check whether phyton and the phyton integration Plug -In have been installed". Is this new, kind of mac thing, why do I need phyton to run SPSS syntax?

 

emel

 

 

---

From: SPSSX(r) Discussion [mailto:[hidden email]] On Behalf Of Samir Omerovic
Sent: Tuesday, April 07, 2009 6:45 AM
To: [hidden email]
Subject: The Marascuillo Procedure or similar

Dear all,

I have following problem: I have sample of 500 respondents who answered a questionnaire. One of the question was to associate different statements with different brands and multiple choice was allowed. So statement 1 could be associated with brand 1, brand 2 etc.... In total I have some 15 statements and 16 brands (and all possible associations are possible). As a result of analysis I would need to calculate in percentages how many respondents associates statement 1 with each of brands etc. and at the end I need to say that percentage of those who associate statement 1 with brand 1 is statistically different from percentage of those who associate statement 1 with brand 2 etc... I am just beginner in statistics and know basics very well but I found Marascuillo procedure to be able to simultaneously test differences in all pairs of proportions but I can not do this in SPSS.
Is there something else I can do in SPSS to calculate this kind of statistics?


Thanks in advance

Samir

===================== To manage your subscription to SPSSX-L, send a message to [hidden email] (not to SPSSX-L), with no body text except the command. To leave the list, send the command SIGNOFF SPSSX-L For a list of commands to manage subscriptions, send the command INFO REFCARD

The information in this e-mail is intended only for the person to whom it is
addressed. If you believe this e-mail was sent to you in error and the e-mail
contains patient information, please contact the Partners Compliance HelpLine at
http://www.partners.org/complianceline . If the e-mail was sent to you in error
but does not contain patient information, please contact the sender and properly
dispose of the e-mail.

[Marta Garcia-Granero]

Samir Omerovic wrote:

......... I found Marascuillo procedure to be able to simultaneously test differences in all pairs of proportions but I can not do this in SPSS.
Is there something else I can do in SPSS to calculate this kind of statistics?

Here it goes (sort of quick&dirty solution, not really elegant in labeling and quality of output, but accurate). Tested with the same example used at http://www.itl.nist.gov/div898/handbook/prc/section4/prc474.htm

* NIST/SEMATECH SAMPLE DATA (replace by your own)  *.
DATA LIST LIST/Lot Result Count(3 F8).
BEGIN DATA
1 0  36
1 1 264
2 0  46
2 1 254
3 0  42
3 1 258
4 0  63
4 1 237
5 0  38
5 1 262
END DATA.
WEIGHT BY Count .
VALUE LABEL Result 0'Non Conformant' 1'Conformant'.
VALUE LABEL Lot 1'G1' 2'G2' 3'G3' 4'G4' 5'G5'.

* MARASCUILLO PROCEDURE *.

* Don't change anything here *.
DATASET NAME Data.
DATASET DECLARE Contingency.
OMS /SELECT TABLES
 /IF COMMANDS = ["Crosstabs"]
     SUBTYPES = ["Crosstabulation"]
 /DESTINATION FORMAT = SAV
  OUTFILE = Contingency.

* Replace "Result" & "Lot" by your variable names *.
CROSSTABS
  /TABLES=Result  BY Lot
  /FORMAT= AVALUE TABLES
  /STATISTIC=CHISQ
  /CELLS= COUNT
  /COUNT ROUND CELL .

* Don't change anything from here to the end *.
OMSEND.
DATASET ACTIVATE Contingency.
DELETE VARIABLES Command_ TO Var3 total.
TEMPORARY.
SET MXLOOPS=200.
MATRIX.
PRINT /TITLE='MARASCUILLO PROCEDURE FOR MULTIPLE PROPORTIONS'.
GET Data /VAR=ALL /NAMES=vnames.
PRINT Data
 /CNAMES=vnames
 /RLABELS='Row 1','Row 2','Total'
 /TITLE='Input data'.
COMPUTE K=NCOL(Data).
COMPUTE P=Data(1,:)&/Data(3,:).
PRINT P
 /FORMAT='F8.3'
 /CNAMES=vnames
 /TITLE='Proportions to be compared'.
COMPUTE N=Data(3,:).
* Critical Chi-square values for up to k=20 *.
COMPUTE Chi2={ 3.8415, 5.9915, 7.8147, 9.4877,11.0705,12.5916,14.0671,15.5073,16.9190,18.3070,
              19.6751,21.0261,22.3620,23.6848,24.9958,26.2962,27.5871,28.8693,30.1435,31.4104}.
COMPUTE Chi2Val=Chi2(K-1).
COMPUTE NComp=K*(K-1)/2.
COMPUTE Rij=    MAKE(NComp,1,0).
COMPUTE ABSDiff=MAKE(NComp,1,0).
COMPUTE Labels= MAKE(Ncomp,3," ").
COMPUTE Sig=    MAKE(NComp,1,'(ns)').
COMPUTE Index=1.
LOOP i=1 TO K-1.
. LOOP j=i+1 TO K.
.  COMPUTE ABSDiff(Index)=ABS(P(i)-P(j)).
.  COMPUTE Rij(Index)=SQRT(Chi2Val)*SQRT(P(i)*(1-P(i))/N(i)+P(j)*(1-P(j))/N(j)).
.  COMPUTE Labels(Index,:)={vnames(i),"vs",vnames(j)}.
.  DO IF (ABSDiff(Index) GT Rij(Index)).
.   COMPUTE Sig(Index)='(*)'.
.  END IF.
.  COMPUTE Index=Index+1.
. END LOOP.
END LOOP.
PRINT {ABSDiff,Rij}
 /FORMAT='F8.3'
 /CLABELS='|Pi-Pj|','Cr. Range'
 /TITLE='Absolute differences and their ranges'.
PRINT {Labels,Sig}
 /FORMAT='A4'
 /TITLE='Contrasts and their significance'.
END MATRIX.
DATASET ACTIVATE Data.
DATASET CLOSE Contingency.

HTH,
Marta García-Granero
===================== To manage your subscription to SPSSX-L, send a message to [hidden email] (not to SPSSX-L), with no body text except the command. To leave the list, send the command SIGNOFF SPSSX-L For a list of commands to manage subscriptions, send the command INFO REFCARD

[Marta Garcia-Granero]

I wrote
> Here it goes (sort of quick&dirty solution, not really elegant in
> labeling and quality of output, but accurate). Tested with the same
> example used at
> http://www.itl.nist.gov/div898/handbook/prc/section4/prc474.htm

Just an addendum I forgot tomention: it's a highly  conservative method
(once I took a lot at the formula I realized it is Scheffe based), and I
have found after a bit of Googling that it is also asymptotic (for big
samples), and nobody has a clear idea of how big  samples should be.

BTW, is it Marascuillo or Marascuilo? I have seen it written both ways

Regards,
Marta

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD

[ViAnn Beadle]

Is this at all related to the test of proportions available in CTABLES which
flags significantly different cells across columns within rows defined by
categories?

-----Original Message-----
From: SPSSX(r) Discussion [mailto:[hidden email]] On Behalf Of
Marta García-Granero
Sent: Tuesday, April 07, 2009 10:00 AM
To: [hidden email]
Subject: Re: The Marascuillo Procedure - done

I wrote
> Here it goes (sort of quick&dirty solution, not really elegant in
> labeling and quality of output, but accurate). Tested with the same
> example used at
> http://www.itl.nist.gov/div898/handbook/prc/section4/prc474.htm

Just an addendum I forgot tomention: it's a highly  conservative method
(once I took a lot at the formula I realized it is Scheffe based), and I
have found after a bit of Googling that it is also asymptotic (for big
samples), and nobody has a clear idea of how big  samples should be.

BTW, is it Marascuillo or Marascuilo? I have seen it written both ways

Regards,
Marta

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD

[Marta Garcia-Granero]

ViAnn Beadle wrote:
> Is this at all related to the test of proportions available in CTABLES which
> flags significantly different cells across columns within rows defined by
> categories?

Samir:

As ViAnn says, if you have the CTABLES module installed (use SHOW LIC to
that find out), you can also use it to get Bonferroni adjusted pairwise
comparisons (a bit more sensitive than Marascuilo method). This is the
syntax (with the same dataset I used for Marascuilo test):

* NIST/SEMATECH SAMPLE DATA (replace by your own)  *.
DATA LIST LIST/Lot Result Count(3 F8).
BEGIN DATA
1 0  36
1 1 264
2 0  46
2 1 254
3 0  42
3 1 258
4 0  63
4 1 237
5 0  38
5 1 262
END DATA.
WEIGHT BY Count .
VALUE LABEL Result 0'Non Conformant' 1'Conformant'.
VALUE LABEL Lot 1'G1' 2'G2' 3'G3' 4'G4' 5'G5'.

CTABLES
  /VLABELS VARIABLES=Lot Result DISPLAY=DEFAULT
  /TABLE Result [COUNT F40.0, COLPCT.COUNT PCT40.1] BY Lot
  /CATEGORIES VARIABLES=Lot Result ORDER=A KEY=VALUE EMPTY=INCLUDE
  /COMPARETEST TYPE=PROP ALPHA=0.05 ADJUST=BONFERRONI ORIGIN=COLUMN
  INCLUDEMRSETS=YES CATEGORIES=ALLVISIBLE.

The only advantage I see for my code is that only BASE module is needed  ;).

Marta

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD

[SPSS Support]

Hello Emel,

 

  You do not need Python to run SPSS syntax on the Mac. I have seen reports of this error when running SPSS syntax in versions 16 or 17 on the Mac. We have not been able to replicate here, according to the reports I have seen. It would help us to see the syntax that triggers the error, as well as a screen shot of the error message dialog. Thanks,

 

David Matheson

SPSS Statistical Support

 

 

---

From: SPSSX(r) Discussion [mailto:[hidden email]] On Behalf Of Ergul, Emel A.
Sent: Tuesday, April 07, 2009 9:26 AM
To: [hidden email]
Subject: moving to mac version of SPSS

 

dear all:

 

finally  I am diverted to the mac version of SPSS v.17. However, every time I run syntax I receive "pyhton scripts cannot be executed. Please check whether phyton and the phyton integration Plug -In have been installed". Is this new, kind of mac thing, why do I need phyton to run SPSS syntax?

 

emel

 

 

 

---

From: SPSSX(r) Discussion [mailto:[hidden email]] On Behalf Of Samir Omerovic
Sent: Tuesday, April 07, 2009 6:45 AM
To: [hidden email]
Subject: The Marascuillo Procedure or similar

Dear all,

I have following problem: I have sample of 500 respondents who answered a questionnaire. One of the question was to associate different statements with different brands and multiple choice was allowed. So statement 1 could be associated with brand 1, brand 2 etc.... In total I have some 15 statements and 16 brands (and all possible associations are possible). As a result of analysis I would need to calculate in percentages how many respondents associates statement 1 with each of brands etc. and at the end I need to say that percentage of those who associate statement 1 with brand 1 is statistically different from percentage of those who associate statement 1 with brand 2 etc... I am just beginner in statistics and know basics very well but I found Marascuillo procedure to be able to simultaneously test differences in all pairs of proportions but I can not do this in SPSS.
Is there something else I can do in SPSS to calculate this kind of statistics?


Thanks in advance

Samir

--

Samir Omerovic
Researcher
___________________________
GfK BH d.o.o.
Skenderija 44
71 000 Sarajevo
Bosnia and Herzegovina
Phone [phone]
Fax [phone]
[hidden email]
www.gfk.ba
<!--[if !supportLineBreakNewLine]-->
<!--[endif]-->

Before printing this e-mail, please consider environment protection.

This e-mail (and any attachment/s) contains confidential and/or privileged information. If you are not the intended recipient (or have
received this e-mail in error) please notify the sender immediately and destroy this e-mail.  Any unauthorized copying, disclosure or
 distribution of the material in this e-mail is strictly forbidden.

Ova e-poruka sadrži povjerljive i/ili povlaštene podatke. Ako niste osoba naznačena kao primalac molimo odmah upozoriti pošiljaoca
i uništiti primljenu e-poruku. Neautorizirano kopiranje, objavljivanje ili distribucija sadržaja iz elektronske poruke striktno je zabranjeno.

---

 

===================== To manage your subscription to SPSSX-L, send a message to [hidden email] (not to SPSSX-L), with no body text except the command. To leave the list, send the command SIGNOFF SPSSX-L For a list of commands to manage subscriptions, send the command INFO REFCARD

The information in this e-mail is intended only for the person to whom it is

addressed. If you believe this e-mail was sent to you in error and the e-mail

contains patient information, please contact the Partners Compliance HelpLine at

http://www.partners.org/complianceline . If the e-mail was sent to you in error

but does not contain patient information, please contact the sender and properly

dispose of the e-mail.

[Samir Omerovic]

Dear Marta,

you are lifesaver. I like your first solution better although both are excellent and working. It is true that my data is dependent since multiple answers are allowed but since I could not found any other procedure that deals with issue I figure out that this is the best I can do for now. I will have to restructure my data to match the given example but it wont be much of a problem I guess.
And I am not sure if it is Marascuillo or Marascuilo either but more references I found have double 'l':)

Thanks once more

Samir

Marta García-Granero wrote:

ViAnn Beadle wrote:

Is this at all related to the test of proportions available in CTABLES which
flags significantly different cells across columns within rows defined by
categories?

Samir:

As ViAnn says, if you have the CTABLES module installed (use SHOW LIC to
that find out), you can also use it to get Bonferroni adjusted pairwise
comparisons (a bit more sensitive than Marascuilo method). This is the
syntax (with the same dataset I used for Marascuilo test):

* NIST/SEMATECH SAMPLE DATA (replace by your own)  *.
DATA LIST LIST/Lot Result Count(3 F8).
BEGIN DATA
1 0  36
1 1 264
2 0  46
2 1 254
3 0  42
3 1 258
4 0  63
4 1 237
5 0  38
5 1 262
END DATA.
WEIGHT BY Count .
VALUE LABEL Result 0'Non Conformant' 1'Conformant'.
VALUE LABEL Lot 1'G1' 2'G2' 3'G3' 4'G4' 5'G5'.

CTABLES
 /VLABELS VARIABLES=Lot Result DISPLAY=DEFAULT
 /TABLE Result [COUNT F40.0, COLPCT.COUNT PCT40.1] BY Lot
 /CATEGORIES VARIABLES=Lot Result ORDER=A KEY=VALUE EMPTY=INCLUDE
 /COMPARETEST TYPE=PROP ALPHA=0.05 ADJUST=BONFERRONI ORIGIN=COLUMN
 INCLUDEMRSETS=YES CATEGORIES=ALLVISIBLE.

The only advantage I see for my code is that only BASE module is needed  ;).

Marta

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD

===================== To manage your subscription to SPSSX-L, send a message to [hidden email] (not to SPSSX-L), with no body text except the command. To leave the list, send the command SIGNOFF SPSSX-L For a list of commands to manage subscriptions, send the command INFO REFCARD

[Swank, Paul R]

No, it is Marascuilo from his book on nonparametric analyses.

 

Dr. Paul R. Swank,

Professor and Director of Research

Children's Learning Institute

University of Texas Health Science Center-Houston

 

From: SPSSX(r) Discussion [mailto:[hidden email]] On Behalf Of Samir Omerovic
Sent: Wednesday, April 08, 2009 2:19 AM
To: [hidden email]
Subject: Re: The Marascuillo Procedure - done

 

Dear Marta,

you are lifesaver. I like your first solution better although both are excellent and working. It is true that my data is dependent since multiple answers are allowed but since I could not found any other procedure that deals with issue I figure out that this is the best I can do for now. I will have to restructure my data to match the given example but it wont be much of a problem I guess.
And I am not sure if it is Marascuillo or Marascuilo either but more references I found have double 'l':)

Thanks once more

Samir

Marta García-Granero wrote:

ViAnn Beadle wrote:

Is this at all related to the test of proportions available in CTABLES which
flags significantly different cells across columns within rows defined by
categories?

Samir:

As ViAnn says, if you have the CTABLES module installed (use SHOW LIC to
that find out), you can also use it to get Bonferroni adjusted pairwise
comparisons (a bit more sensitive than Marascuilo method). This is the
syntax (with the same dataset I used for Marascuilo test):

* NIST/SEMATECH SAMPLE DATA (replace by your own)  *.
DATA LIST LIST/Lot Result Count(3 F8).
BEGIN DATA
1 0  36
1 1 264
2 0  46
2 1 254
3 0  42
3 1 258
4 0  63
4 1 237
5 0  38
5 1 262
END DATA.
WEIGHT BY Count .
VALUE LABEL Result 0'Non Conformant' 1'Conformant'.
VALUE LABEL Lot 1'G1' 2'G2' 3'G3' 4'G4' 5'G5'.

CTABLES
 /VLABELS VARIABLES=Lot Result DISPLAY=DEFAULT
 /TABLE Result [COUNT F40.0, COLPCT.COUNT PCT40.1] BY Lot
 /CATEGORIES VARIABLES=Lot Result ORDER=A KEY=VALUE EMPTY=INCLUDE
 /COMPARETEST TYPE=PROP ALPHA=0.05 ADJUST=BONFERRONI ORIGIN=COLUMN
 INCLUDEMRSETS=YES CATEGORIES=ALLVISIBLE.

The only advantage I see for my code is that only BASE module is needed  ;).

Marta

=====================
To manage your subscription to SPSSX-L, send a message to
[hidden email] (not to SPSSX-L), with no body text except the
command. To leave the list, send the command
SIGNOFF SPSSX-L
For a list of commands to manage subscriptions, send the command
INFO REFCARD

 

--

Samir Omerovic
Researcher
___________________________
GfK BH d.o.o.
Skenderija 44
71 000 Sarajevo
Bosnia and Herzegovina
Phone [phone]
Fax [phone]
[hidden email]
www.gfk.ba

Before printing this e-mail, please consider environment protection.

This e-mail (and any attachment/s) contains confidential and/or privileged information. If you are not the intended recipient (or have
received this e-mail in error) please notify the sender immediately and destroy this e-mail.  Any unauthorized copying, disclosure or
 distribution of the material in this e-mail is strictly forbidden.

Ova e-poruka sadrži povjerljive i/ili povlaštene podatke. Ako niste osoba naznačena kao primalac molimo odmah upozoriti pošiljaoca
i uništiti primljenu e-poruku. Neautorizirano kopiranje, objavljivanje ili distribucija sadržaja iz elektronske poruke striktno je zabranjeno.

---

 

===================== To manage your subscription to SPSSX-L, send a message to [hidden email] (not to SPSSX-L), with no body text except the command. To leave the list, send the command SIGNOFF SPSSX-L For a list of commands to manage subscriptions, send the command INFO REFCARD