coefficient alpha

[Campenni, Estelle]

I am interested in determining if the internal consistency of a battery of
items differs for women and men. Thus, I am interested in determining if the
two Chronbach alphas are significantly different. How would I do this?

Estelle Campenni

[statisticsdoc]

Stephen Brand
www.statisticsdoc.com

Estelle,

One way to address your research question, albeit with a different analysis,
is to conduct a mutli-group Stuctural Equation Model, with AMOS or your
favorite SEM package.  Test a model in which the items load on the relevant
scales.  Test the model separately for males and females.  Constrain the
item loadings to be equal in both samples and see whether this results in a
significantly poorer fit.  If there is a poorer fit, see which item(s)
differ substantially between samples and by how much.
If you have multiple scales, you can also examine whether the scale
intercorrelations are the same for both males and females - a separate but
potentially interesting question.

HTH,

Stephen Brand

For personalized and professional consultation in statistics and research
design, visit
www.statisticsdoc.com


-----Original Message-----
From: SPSSX(r) Discussion [mailto:[hidden email]]On Behalf Of
Campenni, Estelle
Sent: Thursday, September 07, 2006 2:04 PM
To: [hidden email]
Subject: coefficient alpha


I am interested in determining if the internal consistency of a battery of
items differs for women and men. Thus, I am interested in determining if the
two Chronbach alphas are significantly different. How would I do this?

Estelle Campenni

[alexwin]

Dear Estelle,

you can use statistic developed by Feldt. I wrote the following macro to compute it:

define feldt (alpha1 = !tokens(1) / N1 = !tokens(1) / K1 = !tokens(1)
   /alpha2 = !tokens(1) / N2 = !tokens(1) / K2 = !tokens(1)).
input program.
do if (!alpha1 > !alpha2).
  compute alpha1=!alpha1.
  compute K1=!K1.
  compute N1=!N1.
  compute alpha2=!alpha2.
  compute K2=!K2.
  compute N2=!N2.
else.
  compute alpha1=!alpha2.
  compute K1=!K2.
  compute N1=!N2.
  compute alpha2=!alpha1.
  compute K2=!K1.
  compute N2=!N1.
end if.
end case.
end file.
end input program.
execute.
compute W = (1 - alpha1)/(1-alpha2).
compute #c1 = (N1-1)*(K1-1).
compute #c2 = (N2-1)*(K2-1).
compute #a = (N2-1)*#c1/((N2-3)*(#c1-2)).
compute #b = ((N1+1)*(N2-1)**2/((N2-3)*(N2-5)*(N1-1)))*((#c2+2)*#c1**2/((#c1-2)*(#c1-4)*#c2)).
compute df1 = 2*#a**2/(2*#b - #a*#b - #a**2).
compute df2 = 2*#a/(#a-1).
compute sig = CDF.F(W, df1, df2).
report format = list automatic align(center)
  /variables = W df1 df2 sig
  /title "W-test for two independent Alpha".
!enddefine.

This macro needs 6 arguments: alpha, sample size and number of items for each group, for instance --

feldt alpha1=0.700 N1=50 K1=10 alpha2=0.800 N2=50 K2=10.

HTH,

Alex Vinogradov, Associate Professor
Ukraine


> I am interested in determining if the internal consistency of a battery of
> items differs for women and men. Thus, I am interested in determining if the
> two Chronbach alphas are significantly different. How would I do this?

> Estelle Campenni